home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib09.dsk
/
DISK DUMP.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
47 lines
1 REM *******************************
2 REM * DISK DUMP *
3 REM * BY DAVID KRATHWOHL *
4 REM * COPYRIGHT (C) 1982 *
5 REM * BY MICRO-SPARC INC *
6 REM * LINCOLN, MA. 01773 *
7 REM * ALL RIGHTS RESERVED *
8 REM *******************************
10 HOME : VTAB 10: HTAB 10: INVERSE : PRINT " READING DIRECTORY ": NORMAL
20 GOSUB 360: REM POKE IOB INTO MEMORY
30 FOR J = 15 TO 0 STEP -1
40 POKE 783,J: REM STEPS THROUGH SECTORS
50 CALL 768
60 SB = SB +1
70 POKE 787,32 +SB
80 NEXT J
90 DIM CT$(150)
100 DB = 8192:CO = 0:EN = 0:TE = 0
110 FOR I = DB +13 +CO *256 TO DB +(CO +1) *256 STEP 35
120 DE = PEEK(I -2): IF DE = 255 THEN 140: REM DELETED FILE
130 TE = PEEK(I): IF TE = 130 OR TE = 2 THEN 170: REM APPLESOFT FILE
140 TE = 0: NEXT I
150 CO = CO +1: IF CO = 15 THEN 220
160 GOTO 110
170 FOR J = 1 TO 30:CH = PEEK(I +J):CT$(EN) = CT$(EN) + CHR$(CH): NEXT J
180 EN = EN +1
190 TE = 0: NEXT I
200 CO = CO +1: IF CO = 15 THEN 220
210 GOTO 110
220 D$ = CHR$(4)
230 PRINT D$"OPEN DUMPER"
240 PRINT D$"DELETE DUMPER"
250 PRINT D$"OPEN DUMPER"
260 PRINT D$"WRITE DUMPER"
270 FOR K = 0 TO EN -1
280 PRINT "PRINT "; CHR$(34);CT$(K); CHR$(34)
290 PRINT "LOAD ";CT$(K)
300 PRINT "LIST"
305 PRINT "PRINT CHR$(140)": REM FORM FEED ON MX-80
310 NEXT K
320 PRINT "DELETE DUMPER"
330 PRINT D$"CLOSE DUMPER"
340 PRINT D$"EXEC DUMPER"
350 END
360 FOR I = 0 TO 30: READ ML: POKE 768 +I,ML: NEXT I
370 DATA 169,3,160,10,32,217,3,96,0,0,1,96,1,0,17,0,27,3,0,32,0,0,1,0,0,96,1,0,1,239,216
380 RETURN